[SOLVED] How to know if finally is reached because exception?

[lucamar]

In a try...finally block, is there any way to know if the finally is being executed because an exception? I mean, without recurring to an inner try..except or to setting a flag.

In other "words", how to do this:

Code: Pascal  [Select][+][-]

1. GetSomeResource;
2. try
3.   DoSomething; {may raise exception!}
4.   {Note: DoSomething is a placeholder for "lots of lines",
5.     not strictly a function call.}
6. finally
7.   if ExceptionHappened then
8.     TakeHeroicMeasures
9.   else
10.     TakeNormalMeasures;
11.   FreeSomeResource;
12. end;

I know it may sound strange but I need to know if it is possible, although I suppose it isn't. But if anyone can surprise me, please, go ahead!

[dsiders]

In a try...finally block, is there any way to know if the finally is being executed because an exception? I mean, without recurring to an inner try..except or to setting a flag.

In other "words", how to do this:

Code: Pascal  [Select][+][-]

1. GetSomeResource;
2. try
3.   DoSomething; {may raise exception!}
4.   {Note: DoSomething is a placeholder for "lots of lines",
5.     not strictly a function call.}
6. finally
7.   if ExceptionHappened then
8.     TakeHeroicMeasures
9.   else
10.     TakeNormalMeasures;
11.   FreeSomeResource;
12. end;

I know it may sound strange but I need to know if it is possible, although I suppose it isn't. But if anyone can surprise me, please, go ahead!

If DoSomething can raise AND handle an exception, I would make it a Boolean function that indicates that an ExceptionHappened (and was handled) on exit. Then:

Code: [Select]

ExceptionHappened := DoSomething;

Hmm... should have read the comments closer. Disregard.

[wp]

In a try...finally block, is there any way to know if the finally is being executed because an exception?

Initiate a boolean variable to false and set it to true in the line immediately before the "finally". If it is still false inside the "finally" block then an exception must have occured because otherwise the variable would have been set to true:

Code: Pascal  [Select][+][-]

1. var
2.   ok: Boolean;
3. ...
4.   ok := false;
5.   try
6.     ... do something ...
7.     ok := true;
8.   finally
9.     if not ok then Writeln('An exception has happened');
10.   end;

But I don't understand why this is important to you. Normally the "finally" block should not care about exception or not, it should just release resources that were acquired before the "try"

[lucamar]

If DoSomething can raise AND handle an exception, I would make it a Boolean function that indicates that an ExceptionHappened (and was handled) on exit. Then:

Code: [Select]

ExceptionHappened := DoSomething;

That "DoSomething" is just a placeholder; imagine instead a score of lines doing each its thing which may or may not raise an exception. Besides, as stated, I don't want to use a flag (which is trivial, if needed) but capture the exceptional state in the finally section ... if at all possible, that is.

Initiate a boolean variable to false and set it to true in the line immediately before the "finally".
[...]
But I don't understand why this is important to you. [...]

Yeah, as I said above using a flag (or try...except) is trivial; that's not what I wanted.

The "why" is not relevant: you can call it "curiosity" if you want

ETA

To make it clearer: I already know (most of) the conventional ways of dealing with this. What I want to know is if the "unconventional" way is possible some way.

[wp]

Yeah, as I said above using a flag is trivial; that's not what I wanted.

Sorry, I was not reading carefully enough - as usual...

[HeavyUser]

In a try...finally block, is there any way to know if the finally is being executed because an exception? I mean, without recurring to an inner try..except or to setting a flag.

In other "words", how to do this:

Code: Pascal  [Select][+][-]

1. GetSomeResource;
2. try
3.   DoSomething; {may raise exception!}
4.   {Note: DoSomething is a placeholder for "lots of lines",
5.     not strictly a function call.}
6. finally
7.   if ExceptionHappened then
8.     TakeHeroicMeasures
9.   else
10.     TakeNormalMeasures;
11.   FreeSomeResource;
12. end;

I know it may sound strange but I need to know if it is possible, although I suppose it isn't. But if anyone can surprise me, please, go ahead!

I would look for a global exception function or object or stuck rewind pointer etc, probably in the unit that initializes the exceptions (sysutils?) or the forms unit that handles the application exceptions. I think that the objfpc mode either already supports or it is in testing the try..except..finally..end syntax, which I prefer from the existing choices.

[lucamar]

I would look for a global exception function or object or stuck rewind pointer etc, probably in the unit that initializes the exceptions (sysutils?) or the forms unit that handles the application exceptions.

I shall keep looking. So far, I've found gazillion ways to cope with exceptions but nothing that tells you you're inside an exception frame. You know you are when you're responding to one, but when not (directly)?

I think that the objfpc mode either already supports or it is in testing the try..except..finally..end syntax, which I prefer from the existing choices.

That's rather nice. I always though it sounds disrespectful to the program having to use "try {really} try ... except ...finally"

[jamie]

If you are trying to debug a number of steps between the Try and Finally, create a variable, set it to 0 before
you enter the TRY..
  Increment this variable after each step.

 So you'll have Step 1, Step 2 code, etc.

 When FINALLY comes, you can test the variable then..

 This is what I do in cases like this...

 P.S.
   if memory servers I think someone was telling me that even if you  use the EXIT within the try, it'll exit to
FINALLY instead...

 In any case, FINALLY should always be reached.

[ASerge]

In a try...finally block, is there any way to know if the finally is being executed because an exception? I mean, without recurring to an inner try..except or to setting a flag.

Code: Pascal  [Select][+][-]

1. {$MODE OBJFPC}
2. {$APPTYPE CONSOLE}
3.  
4. uses SysUtils;
5.  
6. var
7.   X: TObject;
8. begin
9.   try
10.     X := TObject.Create;
11.     try
12.       Abort;
13.     finally
14.       X.Free;
15.       if Assigned(ExceptObject) then
16.         Writeln('Exception raised')
17.       else
18.         Writeln('Normal finalization')
19.     end;
20.   except
21.     on E: Exception do
22.       Writeln('Error: ', E.Message);
23.   end;
24.   Readln;
25. end.

[lucamar]

Yes, ASerge!!! That's exactly what I wanted!!! Many thanks!


Now I'll have to investigate ExceptObject by myself

[Remy Lebeau]

Now I'll have to investigate ExceptObject by myself

Note that ExceptObject() only works if a TObject-derived object is raised, such as a Sysutils.Exception or descendant.  Which is USUALLY the case, but not always.  Also look at ExceptAddr(), too.

[engkin]

Note that ExceptObject() only works if a TObject-derived object is raised, such as a Sysutils.Exception or descendant.  Which is USUALLY the case, but not always.  Also look at ExceptAddr(), too.

From the code of both functions ExceptObject and ExceptAddr, RaiseList is a better option. Both functions start with:

Code: Pascal  [Select][+][-]

1. begin
2.   If RaiseList=Nil then
3.     Result:=Nil

[lucamar]

From "I don't think it is possible" to "Wow, so many options!"

Thanks everyone, you guys rock!

[PascalDragon]

Now I'll have to investigate ExceptObject by myself

Note that ExceptObject() only works if a TObject-derived object is raised, such as a Sysutils.Exception or descendant.  Which is USUALLY the case, but not always.  Also look at ExceptAddr(), too.

Ehm... in Object Pascal every exception is a descendant of TObject. However not every exception needs to be a descendant of SysUtils.Exception. So ExceptObject will always be assigned if an exception occurred (and has not yet been handled by an exception handler).

[lucamar]

I (finally) wrote a little test: just a form with a button and an exception-raising procedure wich gets called in the button's OnClick handler. Relevant code:

Code: Pascal  [Select][+][-]

1. procedure TForm1.RunIfYouDare(const WithException: Boolean);
2. { Let's check with and without a declared object.
3.   Note: e: Exception is a field of the form }
4. begin
5.   if WithException then begin
6.     e := Exception.Create('You dared!');
7.     raise e;
8.   end else
9.     raise Exception.Create('You (almost) dared!');
10. end;
11.  
12. procedure TForm1.Button1Click(Sender: TObject);
13. begin
14.   try
15.     RunIfYouDare(); { Should raise an exception }
16.   finally
17.     if Assigned(ExceptObject) then
18.       ShowMessage(
19.           'As expected: an exception.' + LineEnding +
20.           Format('She says: "%s"',[(ExceptObject as Exception).Message])
21.         )
22.     else
23.       ShowMessage('The unexpected happened ... no exception!');
24.   end;
25. end;

Since the exception is not treated in anyway (no except block) it stays raised and bubbles up. The result(s) can be seen in the attached images.

Many thanks again to everyone.